Programación Web y Scripting > ASP
Cdo Error 8004020c
(1/1)
oonai:
Saludos
tengo un problema con el codigo de CDO, el error es
CDO.Message.1 error '8004020c'
At least one recipient is required, but none were found.
/enviaremail.asp, line 58
CODIGO
<%@ LANGUAGE=VBScript %>
<HTML>
<HEAD>
<TITLE>Arconet - Colinas de los Ruices</TITLE>
<META HTTP-EQUIV="Content-type" CONTENT="text,html ; charset=iso-8859-1">
<META name="author" content="Corporación GMO C.A. - 0414.204.78.21 - 0414.209.83.34">
</HEAD>
</HEAD>
<BODY>
<%
fecha = request.form("fecha")
email = request.form("email")
dirigido = request.form("dirigido")
titulo = request.form("titulo")
mensaje = request.form("contenido")
key = request.form("key")
session("mensaje")=""
Select Case key
Case "1":
retorno = "arcoreclamo.asp"
session("mensaje")="Su reclamo o denuncia esta siendo procesada. Gracias."
tipo="Reclamo"
remitir="gpaviles@yahoo.com"
Case "2":
retorno = "contactos.asp"
Case "3":
retorno = ""
Case "4":
retorno = ""
End Select
msg = tipo & " : " & chr(10) & chr(10)
msg = msg & "Dirigido a : " & dirigido & chr(10)
msg = msg & "fecha : " & fecha & chr(10)
msg = msg & "Email : " & email & chr(10)
msg = msg & "Titulo : " & titulo & chr(10)
msg = msg & "Mensaje : " & mensaje & chr(10)
Set objEmail = CreateObject("CDO.Message")
objEmail.From = email
objEmail.To = remitir
objEmail.Subject = "Arcorui.net " & tipo
objEmail.Textbody = msg
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
"smtpmailer"
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objEmail.Configuration.Fields.Update
Err.Clear
objEmail.Send ' ESTA ES LA LINEA 58 !!!!!
if err <> 0 then
response.Write(" ERROR:"&err.description&" codigo:"&err)
end if
Set objFields = Nothing
Set objConf = Nothing
Set objEmail = Nothing
Response.Redirect retorno
%>
</BODY>
</HTML>
Este programa recibe informacion de correo y envia el email, desde distintos sitios de la pagina y lo reenvia a personas diferentes segun el caso, pero no camina, agradezco alguna idea GRACIAS De antemano
oonai:
Funciono por fin, aqui esta el codigo, por si alguien lo necesita. Es un manejador de reclsamos y de contactos
<%@ LANGUAGE=VBScript %>
<HTML>
<HEAD>
<TITLE>Arconet - Colinas de los Ruices</TITLE>
<META HTTP-EQUIV="Content-type" CONTENT="text,html ; charset=iso-8859-1">
<META name="author" content="Corporación GMO C.A. - 0414.204.78.21 - 0414.209.83.34">
<!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" NAME="CDO for Windows Library" -->
<!--METADATA TYPE="typelib" UUID="00000205-0000-0010-8000-00AA006D2EA4" NAME="ADODB Type Library" -->
</HEAD>
<BODY>
<%
'blanqueo de sessiones
session("rfecha")=""
session("remail")=""
session("rdirigido")=""
session("rtitulo")=""
session("rcontenido")=""
session("mensaje")=""
'capturo informacion
fecha = request.form("fecha")
email = request.form("email")
dirigido = request.form("dirigido")
titulo = request.form("titulo")
contenido = request.form("contenido")
key = request.form("key")
'cargo sessiones para la confirmacion de envio
session("rfecha")=fecha
session("remail")=email
session("rdirigido")=dirigido
session("rtitulo")=titulo
session("rcontenido")=contenido
'selecciono retorno y la data para usos multiples del mismo programa
Select Case key
Case "1":
continuar = "envreclamo.asp"
session("mensaje")="Su reclamo o denuncia está siendo procesada , por Arcorui. Gracias."
enviara="mariettaperroni@yahoo.com"
tipo="RECLAMO"
tituloemail="RECLAMO"
Case "2":
continuar = "envcontacto.asp"
session("mensaje")="Su email sera procesasdo a la brevedad , por Arcorui. Gracias."
enviara="mariettaperron@yahoo.com"
tipo="CONTACTO"
tituloemail="CONTACTO"
End Select
'creo el mensaje a enviar
msg = tipo & " : " & chr(10) & chr(10)
msg = msg & "Para : " & dirigido & chr(10)
msg = msg & "Fecha : " & fecha & chr(10)
msg = msg & "Email : " & email & chr(10)
msg = msg & "Titulo : " & titulo & chr(10)
msg = msg & "Mensaje : " & contenido & chr(10)
'
'
' inicio de opciones
' Creo Objetos
Dim ObjSendMail
Dim iConf
Dim Flds
' Inicio objetos
Set ObjSendMail = Server.CreateObject("CDO.Message")
Set iConf = Server.CreateObject("CDO.Configuration")
Set Flds = iConf.Fields
With Flds
.Item(cdoSendUsingMethod) = 2
.Item(cdoSMTPServer) = "mail-fwd"
.Item(cdoSMTPServerPort) = 25
.Item(cdoSMTPconnectiontimeout) = 10
.Update
End With
Set ObjSendMail.Configuration = iConf
Set ObjSendMail.Configuration = iConf
ObjSendMail.To = enviara
ObjSendMail.Subject = tituloemail
ObjSendMail.From = email
ObjSendMail.TextBody = msg
ObjSendMail.Send
Set ObjSendMail = Nothing
Set iConf = Nothing
Set Flds = Nothing
Response.Redirect continuar
%>
espero que este modelo le sirva a otro usuario de este portal
Manejo de email con CDO
Navegación
Ir a la versión completa