• Sábado 16 de Noviembre de 2024, 02:46
« anterior próximo »
Páginas: [1]

Autor Tema:  Alv Y Top_of_page  (Leído 4146 veces)

senzao18

  • Miembro HIPER activo
  • ****
  • Mensajes: 553
    • Ver Perfil
Alv Y Top_of_page
« en: Viernes 20 de Octubre de 2006, 19:01 »
0
Estoy haciendo un ALV el caso es que le pongo el evento TOP_OF_PAGE para mostrar unos textos al inicio de la ventana....  El problema esta que cuando uso el REUSE_ALV_LIST_DISPLAY si sale bien el texto... pero cuando uso el
REUSE_ALV_GRID_DISPLAY no me muestra el texto sino un recuadro Gris sin el texto  que yo  mando con la instruccion Write  :huh: ....

Soy nuevo en esto de los ALV tienen alguna idea de por donde va el problema o simplemente no se puede... <_<
---------------------------------------
Erick Aragon Zepeda
Dessarrollo de Aplicaciones .NET
http]
Blog de Articulos
Mi Blog
NoSolocodigo -->

Blag

  • Moderador
  • ******
  • Mensajes: 697
    • Ver Perfil
    • http://atejada.blogspot.com
Re: Alv Y Top_of_page
« Respuesta #1 en: Viernes 20 de Octubre de 2006, 19:28 »
0
Yo siempre lo he hecho utilizando el REUSE_ALV_GRID_DISPLAY  B)

Código: Text
  1.  
  2. DATA: GT_LIST_TOP_OF_PAGE TYPE SLIS_T_LISTHEADER.
  3. DATA: I_EVENTS   TYPE SLIS_T_EVENT.
  4.  
  5. FORM TOP_OF_PAGE.
  6.   CALL FUNCTION 'REUSE_ALV_COMMENTARY_WRITE'
  7.        EXPORTING
  8.             IT_LIST_COMMENTARY = GT_LIST_TOP_OF_PAGE.
  9. ENDFORM.
  10.  
  11. PERFORM F_FORMATO_PAGE CHANGING GT_LIST_TOP_OF_PAGE.
  12. PERFORM F_FORMATEAR_EVENTOS_ALV USING I_EVENTS[].
  13. PERFORM F_GENERAR_LISTA_ALV.
  14.  
  15. FORM F_FORMATEAR_EVENTOS_ALV USING P_EVENTS TYPE SLIS_T_EVENT.
  16.   DATA: L_EVENTS TYPE SLIS_ALV_EVENT.
  17.  
  18.   CLEAR L_EVENTS.
  19.   L_EVENTS-NAME = 'TOP_OF_PAGE'.
  20.   L_EVENTS-FORM = 'TOP_OF_PAGE'.
  21.   APPEND L_EVENTS TO P_EVENTS.
  22. ENDFORM.
  23.  
  24. FORM F_FORMATO_PAGE CHANGING GT_TOP_OF_PAGE TYPE SLIS_T_LISTHEADER.
  25. DATA: GS_LINE TYPE SLIS_LISTHEADER.
  26.  
  27. CLEAR GS_LINE.
  28.   GS_LINE-TYP  = 'H'.
  29.  
  30.   CONCATENATE SY-DATUM+6(2) '.' SY-DATUM+4(2) '.'
  31.               SY-DATUM+0(4) INTO FECHA_PROCESO.
  32.  
  33. *-----Fecha de Proceso
  34.   CONCATENATE 'Fecha de Proceso:' FECHA_PROCESO
  35.   INTO GS_LINE-INFO
  36.   SEPARATED BY SPACE.
  37.   APPEND GS_LINE TO GT_TOP_OF_PAGE.
  38. ENDFORM.
  39.  
  40. FORM F_GENERAR_LISTA_ALV.
  41.   G_PROGRAM = SY-REPID.
  42.   G_TITULO = SY-TITLE.
  43.  
  44.   CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
  45.        EXPORTING
  46.             I_BUFFER_ACTIVE    = ' '
  47.             I_CALLBACK_PROGRAM = G_PROGRAM
  48.             IS_LAYOUT          = GS_LAYOUT
  49.             I_SAVE             = 'A'
  50.             I_GRID_TITLE       = G_TITULO
  51.             IT_FIELDCAT        = I_FIELDCAT
  52.             IT_SORT            = GS_SORT[]
  53.             IT_EVENTS          = I_EVENTS
  54.        TABLES
  55.             T_OUTTAB           = T_SALIDA
  56.        EXCEPTIONS
  57.             PROGRAM_ERROR      = 1
  58.             OTHERS             = 2.
  59.  
  60.   IF SY-SUBRC NE 0.
  61.     EXIT.
  62.   ENDIF.
  63. ENDFORM.
  64.  
  65.  

Disculpa que no esté muy ordenado  :P

Saludos,

Blag  :smartass:

miguelig81

  • Nuevo Miembro
  • *
  • Mensajes: 1
    • Ver Perfil
Re: Alv Y Top_of_page
« Respuesta #2 en: Lunes 23 de Octubre de 2006, 17:00 »
0
hola bueno yo utilizo este form
*&---------------------------------------------------------------------*
*&      Form  build_eventtab
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->P_EVENTS[]  text
*----------------------------------------------------------------------*
FORM build_eventtab  USING   p_events TYPE slis_t_event.

  DATA: ls_event TYPE slis_alv_event.
*  Returns table of possible events for a list type
  CALL FUNCTION 'REUSE_ALV_EVENTS_GET'
    EXPORTING
      i_list_type = 0
    IMPORTING
      et_events   = p_events.
*  slis_ev_top_of_page
  READ TABLE p_events WITH KEY name = slis_ev_top_of_page
                           INTO ls_event.
  IF sy-subrc = 0.
    MOVE formname_top_of_page TO ls_event-form.
    APPEND ls_event TO p_events.
  ENDIF.

  READ TABLE p_events WITH KEY name = slis_ev_pf_status_set
                            INTO ls_event.
  IF sy-subrc = 0.
    MOVE formname_pf_status TO ls_event-form.
    APPEND ls_event TO p_events.

  ENDIF.

ENDFORM.                    " build_eventtab

y pones tambien

*---------------------------------------------------------------------*
*       FORM TOP_OF_PAGE                                              *
*---------------------------------------------------------------------*
FORM top_of_page.
  CALL FUNCTION 'REUSE_ALV_COMMENTARY_WRITE'
    EXPORTING
      it_list_commentary = heading.
ENDFORM.                    "TOP_OF_PAGE

*---------------------------------------------------------------------*
*       FORM pf_status_set
*---------------------------------------------------------------------*
FORM pf_status_set USING                                    "#EC CALLED
                   pu_tab_excl_okcode TYPE slis_t_extab.

  SET PF-STATUS 'ALV_STATUS'.
  SET TITLEBAR 'TITULO1'.


ENDFORM.                    "pf_status_set
*&---------------------------------------------------------------------*
*&      Form  build_comment
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->P_HEADING[]  text
*----------------------------------------------------------------------*
FORM build_comment  USING    p_heading TYPE slis_t_listheader.

  DATA: hline    TYPE slis_listheader,
        text(60) TYPE c,
        sep(20)  TYPE c,
        proceso TYPE i,
        w_fecha(20)  TYPE c,
        w_hora(10) TYPE c,
        w_usuario(15) TYPE c,
        w_numero TYPE i.

  CONCATENATE sy-datum(4) '.' sy-datum+4(2) '.' sy-datum+6(2)  INTO w_fecha.
  CONCATENATE sy-uzeit(2) ':' sy-uzeit+2(2) ':' sy-uzeit+4(2)  INTO w_hora.


*  Cabecera
  CLEAR hline.
  hline-typ  = 'H'.
  hline-info =  text-ti2.
  APPEND hline TO p_heading.

  CLEAR hline.
  hline-typ  = 'S'.
  hline-key  = text-fec.
  hline-info = w_fecha.
  APPEND hline TO p_heading.

  CLEAR hline.
  hline-typ  = 'S'.
  hline-key  = text-hor.
  hline-info = w_hora.
  APPEND hline TO p_heading.


  CLEAR hline.
  hline-typ  = 'S'.
  hline-key  = text-usu.
  hline-info = sy-uname.
  APPEND hline TO p_heading.

con este codigo armas y muestra en tu alv, el titulo, la hora, la fecha y el usuario.
ojala te ayude  :D

senzao18

  • Miembro HIPER activo
  • ****
  • Mensajes: 553
    • Ver Perfil
Re: Alv Y Top_of_page
« Respuesta #3 en: Lunes 23 de Octubre de 2006, 17:36 »
0
Gracias a los dos... ahorita no tengo chance de probar lo que postearon.. ya ves como son las empresas.... "No es prioridad mostrar el texto" jeje....

Luego les digo como me fue con esto....
---------------------------------------
Erick Aragon Zepeda
Dessarrollo de Aplicaciones .NET
http]
Blog de Articulos
Mi Blog
NoSolocodigo -->
Páginas: [1]
« anterior próximo »